Excel’de EĞERHATA (IFERROR ) İşlevi Nasıl Kullanılır

EĞERHATA işlevinin ne olduğu ve Excel’deki hataları işlemek için nasıl kullanılacağı hakkında bilmeniz gereken her şey burada.

EĞERHATA işlevi, Excel’deki formüllerden kaynaklanan hataları işlemek için tasarlanmıştır. EĞERHATA işlevi, formüllerdeki hataları algılamak için kullanılan ve alternatif bir değer döndüren veya hatanın yerine başka bir hesaplama yapan mantıksal bir formüldür. EĞERHATA işlevinin içine yerleştirilmiş formül bir hatayla sonuçlanırsa, EĞERHATA işlevi bu hatayı yakalar ve yerine belirtilen bir değeri döndürür.

Excel, formülde veya başvurduğu hücrede yanlış bir şey olduğunda hataları gösterir, ancak bazen hata kaçınılmazdır. Hata olması yalnızca hesap tablonuzun kötü görünmesine neden olmakla kalmaz, başka bir formül bu hatayı içeren hücreye başvurursa (örneğin bir hücre aralığını topladığınızda), ikinci formülde başka bir hataya neden olur. Bu nedenle, bir hata görüntülemek yerine, EĞERHATA işlevini sıfır, boş veya metin gibi başka bir şey döndürmek için kullanabilirsiniz.

EĞERHATA işlevi, hataları ele almanın ve elektronik tablolarınızı temiz ve formüllerinizi şeffaf tutmanın kolay ve zarif bir yoludur. Ayrıca, bu işlev Excel’in tüm Excel 2007 sürümlerinde kullanılabilir. Bu öğreticide, EĞERHATA işlevinin ne olduğunu ve Excel’deki hataları yönetmek için nasıl kullanılacağını öğreneceğiz.

Excel’de EĞERHATA İşlevi nedir?

EĞERHATA işlevi, iç içe geçmiş formül bir hatayla sonuçlanırsa belirtilen bir değer döndüren yerleşik bir işlevdir.

EĞERHATA işlevinin Sözdizimi:

=IFERROR(value,value_if_error)

İşlevin yalnızca iki argümanı vardır:

Ayrıca, herhangi bir hata bulunmazsa, bağımsız değişkendeki formülün veya ifadenin olağan sonucunu valuedöndürür.

EĞERHATA işlevini aşağıdakiler gibi çeşitli formül hatalarını algılamak ve işlemek için kullanabilirsiniz:

Çoğu zaman bu hatalarla karşılaştığınızda formülü düzelterek sorunu çözebilirsiniz. Ancak bazen bu hatalar kaçınılmazdır ve bunları bekliyor olabilirsiniz. Bu nedenle, bu hatalarla başa çıkmak için, hatanın yerine bir değer veya işlev koymak için EĞERHATA işlevini kullanabilirsiniz.

EĞERHATA işlevini başka bir benzer hata denetimi işleviyle, hataları kontrol etmek ve basit DOĞRU veya YANLIŞ döndürmek için kullanılan EĞERHATA işleviyle karıştırmayın.

EĞERHATA işlevi nasıl kullanılır

EĞERHATA işlevini kullanarak hataları nasıl yakalayabileceğimizi ve örneklerle hatalar yerine farklı türde değerler döndürmeyi görelim.

Hata Olursa 0 Döndür

Formülünüzde bir hatayla karşılaşırsanız, EĞERHATA işlevini kullanarak hata yerine ‘0’ döndürebilirsiniz.

Örnek 1:

Örneğin aşağıdaki örnekte farklı kalemlerin ortalama satışlarını bulmak istedik ve A sütunundaki Satış değerlerini B Sütunundaki Miktar (Kalite) değerlerine böldük.

Tabloda, B2’deki Miktar değeri 0’dır ve A5’teki satış değeri bir #N/A (Mevcut değil) hatasıdır. Sonuç olarak #SAYI/0! C2’de, çünkü herhangi bir sayı 0’a (bölen) bölündüğünde, Excel #SAYI/0! hata. Ve #N/A hatası 50’ye bölündüğünde, karşılığında başka bir #N/A hatası çıktı.

EĞERHATA fonksiyonu yardımıyla hata kodlarını görüntülemek yerine sonuç olarak ‘0’ döndürebiliriz.

Hataları işlemek için formülü EĞERHATA işlevinin içine yerleştirebilirsiniz:

=IFERROR(A2/B2,0)

Aşağıdaki örnekte EĞERHATA fonksiyonunu aynı formülle birleştirdik ve ayrı bir sütuna girdik. Yukarıdaki formül D2 hücresine girilir ve doldurma tutamacı kullanılarak tüm sütuna kopyalanır. Aşağıda görebileceğiniz gibi formül bir hata tespit ettiğinde Ortalama satış fiyatı olarak ‘0’ döndürür.

Örnek 2:

EĞERHATA işlevindeki ikinci bağımsız değişkeni yok sayarsanız, formül varsayılan olarak ‘0’ döndürür.

=IFERROR(A2/B2,)

Hata Olursa, Boş Döndür

Hataların yerine 0 value_if_errorkoymak yerine, sonuç bir hataysa boş bir hücre döndürmek için EĞERHATA argümanında boş bir dize (“) belirtirsiniz.

Örnek 1:

Bir hata bulunursa boş bir hücre döndürmek için aşağıdaki formülü kullanın:

=IFERROR(A2/B2,"")

Formülde, boş bir hücre döndürmek için boş bir dize anlamına gelen çift tırnak (“”) girdik.

Örnek 2:

EĞERHATA işlevini kullanarak boş bir hücre yerine bir hatayı değiştirmek için herhangi bir sembolü de kullanabilirsiniz.

Bir hata bulunursa bir sembol veya karakter döndürmek için aşağıdaki formülü kullanın:

=IFERROR(A2/B2,"-")

Hata Olursa, Bir Mesaj/Metin Dizesi Göster

0 veya boş veya bir hata göstermek yerine EĞERHATA işlevini kullanarak kendi mesajınızı görüntüleyebilirsiniz. EĞERHATA işlevinin ikinci bağımsız değişkenine bir metin dizesi eklediğinizde, onu çift tırnak içine aldığınızdan emin olun.

Örneğin, bu formül, hata kodu yerine “Geçersiz giriş” mesajını döndürür:

=IFERROR(A2/B2,"Invalid Input")

Hata Olursa Bir Hesaplama Yapın

EĞERHATA işlevi ile ilk formül bir hata olarak değerlendirilirse ikinci bir hesaplama yapabilirsiniz. value_if_errorEĞERHATA argümanına ikinci formülü girerek bunu başarabilirsiniz .

Örneğin, bir ürünün fiyatını Stok 1 miktarı ile çarparak Stok 1’in satışlarını bulmak istiyoruz. Ancak elimizde iki adet stok yok, bu yüzden fiyat tire (-) sembolü ile çarpıldığında Value hatası alıyoruz.

Bu nedenle, stok 1 miktarını fiyatla çarpmak bir hatayla sonuçlanırsa, her bir öğenin satış miktarını bulmak için stok 2 miktarını fiyatla çarpın:

=IFERROR(B2*C2,B2*D2)

Yukarıdaki formülde B2’yi C2 ile çarparken hata veriyor, EĞERHATA işlevi B2’yi D2 ile çarpar ve satış tutarını döndürür. EĞERHATA işlevinin içindeki ilk formül bir hatayla sonuçlanmadıysa, o sonucu döndürür.

Dizi Formülleriyle EĞERHATA

Dizi formülü, tek bir formül aracılığıyla bir dizide birden çok hesaplama yapmak için kullanılır. Ancak bazen Dizi formülleri de hatalara neden olabilir.

Örneğin, A sütunundaki değeri her satırdaki B sütunundaki bir değere bölerek ve sonuçları toplayarak aşağıdaki tablonun toplam ortalama satışını bulmak istiyoruz. Ancak aşağıdaki dizi formülünü kullandığımızda bir hatayla sonuçlanır:

=SUM(A2:A6/B2:B6,0)

Yukarıdaki formül, A2:A6 aralığındaki her hücre değerini, B2:B6 aralığının karşılık gelen hücre değerine böler ve bu dizi sonuç dizisini döndürür {#DIV/0!,33.33,15,#N/A,133.32}. Ardından, SUM işlevi, aynı zamanda bir hatayla sonuçlanan toplam ortalama satışları üretmek için sonuç dizisini toplar.

Formül, A2’deki değerleri 0’a ve A5’teki hatayı B5’e bölerek iki hataya neden olur. Ve bu iki hata değeri diğer değerlerle toplandığında bir #SAYI0! hata.

Bu sorunu çözmek için, bölme işlemini EĞERHATA işlevinin içine almanız ve EĞERHATA işlevini SUM işleviyle sarmanız yeterlidir:

=SUM(IFERROR(A2:A6/B2:B6,0))

Dizi formülünü yürütmek için Ctrl+ Shift+ tuşlarına basın Enter.

EĞERHATA işlevi tüm hataları yakalar ve bunları 0 ile değiştirerek şu sonuç dizisini oluşturur – {0,33.33,15,0,133.32). Ardından, SUM işlevi tüm sonuçları toplar ve ‘181.65’ değerini döndürür.

DÜŞEYARA işlevli EĞERHATA

EĞERHATA işlevi, arama değeri veri kümesinde yoksa özel bir mesaj veya metin döndürmek için genellikle DÜŞEYARA işleviyle birleştirilir.

DÜŞEYARA işlevi, bir tablonun veya aralığın ilk sütununda bir değer arar ve buna karşılık gelen değeri bir sütundan sağa doğru çıkarır. Ancak, arama değeri tabloda bulunamazsa veya yanlış yazılmışsa, bir #YOK! karşılığında hata. Bu nedenle, elektronik tablonuzu düzenlemek için, hatalar yerine kendi mesajınızı döndürmek için EĞERHATA işlevini kullanabilirsiniz.

Misal:

Bir öğrencinin adını aramak ve belirli bir konudan puanını çıkarmak istediğiniz aşağıdaki verilere sahip olduğunuzu varsayalım.

‘Roger’ (J5) adlı bir öğrenciyi aramak ve biyoloji puanını döndürmek için aşağıdaki formülü kullanabiliriz:

=VLOOKUP(J5,A2:G15,5,FALSE)

Bununla birlikte, J5 ‘Roger’ hücresindeki arama değeri tabloda bulunmadığından, yukarıdakiler bir hatayla sonuçlanır. Burada, ilk argüman J5arama değerini belirtir, A2:G15 aralığı temsil eder, 5fonksiyona beşinci sütundan değerleri almasını söyler ve FALSEtam değeri arama anlamına gelir.

Değer bulunamazsa, hata durumunda “Bulunamadı” veya “yanlış giriş” gibi özel bir metin dizesi döndürmek için EĞERHATA işlevini kullanabilirsiniz. Bunu yapmak için, DÜŞEYARA formülünü ilk argüman olarak ve döndürmek istediğiniz metin dizesini EĞERHATA formülü içinde ikinci argüman olarak sarmanız gerekir.

Özel bir metin dizesi döndürmek için DÜŞEYARA işlevi bir hata olarak değerlendirilirse aşağıdaki formülü girin:

=IFERROR(VLOOKUP(J5,A2:G15,5,FALSE),"Not Found")

Yukarıdaki formül, ‘A2:G15’ aralığında ‘Roger’ (J5) değerini arar ve değer tabloda bulunmadığından bir #YOK hatası oluşturur. Ancak EĞERHATA işlevi bu hatayı yakalar ve yerine belirtilen “Bulunamadı” dizesini döndürür.

İç içe DÜŞEYARA işlevi bir hataya neden olmazsa, EĞERHATA işlevi yalnızca DÜŞEYARA işlevinin standart sonucunu döndürür.

Örneğin, arama değerini ‘Roger’ yerine ‘Robert’ olarak değiştirirseniz, aşağıdaki sonucu alırsınız:

Burada aynı formülü kullandık ama sadece formülün giriş değerini ‘Robert’ olarak değiştirdik. Sonuç olarak Biyoloji dersi için ’86’ puanını alıyoruz.

EĞERHATA Sıralı Vlookups Gerçekleştirme İşlevi 

EĞERHATA işlevi, önceki aramanın bir hatayla sonuçlanıp sonuçlanmadığına bağlı olarak birden çok Vlookup veya sıralı Vlookup gerçekleştirmek için de kullanılabilir.

Sınıf 1 ve Sınıf 2 için çeşitli konulardaki öğrenci puanlarının bir listesine sahip olduğunuzu ve Vlookup kullanarak belirli bir öğrencinin belirli bir konudaki sınav puanını sınıf 1’den çıkarmak istediğinizi varsayalım.

Ancak aradığınız öğrenci 1. Sınıfta bulunamazsa hata alırsınız. Dolayısıyla, EĞERHATA işlevinin iki bağımsız değişkeni olarak iki DÜŞEYARA işlevini (biri Sınıf 1 için ve diğeri Sınıf 2 için) yuvalarsanız, 2. DÜŞEYARA işlemini gerçekleştirir ve ilk DÜŞEYARA bir hatayla sonuçlanırsa sonuçları döndürür.

EĞERHATA ile sıralı DÜŞEYARA yapmak için aşağıdaki formülü kullanın:

=IFERROR(VLOOKUP(H17,A3:G12,3,FALSE),VLOOKUP(H17,I3:O13,3,FALSE))

Yukarıdaki formülde, ilk Vlookup işlevi, A3:G12 (Sınıf 1) dizisini arayarak H17’deki (Django) değeri arar ve arama değeri bulunursa, sütun 3’teki (Fizik puanı) karşılık gelen değeri döndürür. İlk DÜŞEYARA, Sınıf 1’deki değeri bulamazsa, I3:O13 (Sınıf 2) aralığındaki değerleri arayan ve öğrenci Django için Fizik puanını veren ikinci Vlookup’a geçer.

Sıralı Vlookup’lar için iç içe EĞERHATA işlevleri

Ancak, ikinci Vlookup da arama değerini bulamazsa ve yukarıdaki formülde başarısız olursa, o zaman bir hata alırız. Bunu önlemek için, arama değeri her iki dizide de bulunmazsa, özel bir mesaj döndürmek için bir formül oluşturmanız gerekir.

İlk bağımsız değişken (değer) olarak ilk DÜŞEYARA ve ikinci bağımsız değişken (değer_eğer_hata) olarak başka bir EĞERHATA işlevi ile bir EĞERHATA formülü oluşturmanız gerekir. Ardından, ikinci DÜŞEYARA ve bir value_if_error mesajını ikinci EĞERHATA işlevinde iç içe geçirin:

=IFERROR(VLOOKUP(H17,A3:G12,3,FALSE),IFERROR(VLOOKUP(H17,I3:O13,3,FALSE),"Enter a valid name"))

1. EĞERHATA içindeki ilk Vlookup, A3:G12 dizisindeki ‘Dan’ değerini arar ve başarısız olursa, 2. EĞERHATA içindeki ikinci Vlookup, I3:O3 aralığındaki ‘Dan’ değerini arar. Aynı zamanda başarısız olursa, 2. EĞERHATA belirtilen “Geçerli bir ad girin” mesajını verir.

EĞERHATA, INDEX MATCH işleviyle

İNDEKS ve KAÇINCI işlevi, bir hücre aralığında belirli bir değeri aramanıza ve belirtilen satır ve sütun kesişiminde bir değer döndürmenize olanak tanıyan DÜŞEYARA işlevinden daha gelişmiş güçlü bir arama işlevidir.

DÜŞEYARA ile olduğu gibi, INDEX MATCH işlevi verilen aralıkta aramayı bulamazsa, hata mesajını döndürür. Bu gibi durumlarda, EĞERHATA işlevini alternatif bir mesaj üretmek için kullanabilir veya INDEX MATCH işlevini yuvalayarak başka bir aralıktaki değeri arayabiliriz.

Misal:

=IFERROR(INDEX(A2:G11,MATCH(D14,A2:A11,0),4),"Not available")

Yukarıdaki formülde, KAÇINCI işlevi A2:A11 aralığında arama değerinin konumunu bulmaya çalışır, ancak arama değeri dizide bulunmadığından EĞERHATA, verilen alternatif “Kullanılamaz” dizesini döndürür.

EĞER ve EĞERHATA işlevi

Gelişmiş bir formül oluşturmak ve hataları işlemek için EĞERHATA işlevini EĞER işleviyle de birleştirebilirsiniz.

Örneğin, öğrenci Margaret’in tablodaki EĞER işlevini kullanarak başarılı mı yoksa başarısız mı olduğunu kontrol etmek istiyoruz. Ancak Margaret’in puanı tabloda mevcut değil, bu nedenle sonuç olarak #N/A hatası alıyoruz.

Bunu düzeltmek için aşağıdaki EĞER ve EĞERHATA fonksiyon kombinasyonunu kullanabiliriz:

=IFERROR(IF(B5>50,"Pass","Fail"),"Score not available")

Burada EĞER işlevi, B5’teki değerin 50’den büyük olup olmadığını kontrol eder ve bir hata döndürür. Ardından EĞERHATA işlevi bu hatayı yakalar ve bunun yerine verilen alternatif metin dizesini görüntüler.

IFERROR ve ISERROR

ISERROR işlevi, bir formülün hata olarak değerlendirilip değerlendirilmediğini kontrol etmek ve sonuç olarak DOĞRU veya YANLIŞ döndürmek için kullanılan başka bir hata işleme işlevidir. EĞERHATA işlevi, formül bir hatayla sonuçlanırsa alternatif bir değer döndürür.

ISERROR’un sözdizimi:

=ISERROR(value)

ISERROR işlevi (mantıksal koşul), bir işlemi yürütmek veya mantıksal koşul bir hatayla sonuçlanırsa bir değer döndürmek ve bir hatayla sonuçlanmıyorsa ne yapılması gerektiğini EĞER işleviyle birlikte kullanılır.

Örneğin, bu IF ISERROR formülünü kullanarak Janet’in Biyolojideki işaretlerini çıkarmak istiyoruz:

=IF(ISERROR(VLOOKUP(H5,A2:G15,5,FALSE)),"Student not found",VLOOKUP(H5,A2:G15,5,FALSE))

Burada ISERROR, iç içe Vlookup formülünün bir hatayla sonuçlanıp sonuçlanmadığını kontrol eder. DOĞRU ise, EĞER işlevi “Öğrenci bulunamadı” mesajını döndürür, aksi takdirde Vlookup işlevini tekrar gerçekleştirir ve ’98’ puanını döndürür.

Aranan değer (öğrenci) bulunamazsa:

veya öğrencinin adı bulunursa:

IFNA ve EĞERHATA

EĞERHATA, EĞERHATA tüm hata türlerini işlerken yalnızca #YOK hatalarını yakalamak için kullanılan EĞERHATA’ya benzer başka bir hata denetimi işlevidir. IFNA formülü, diğer tüm hatalar için değil de yalnızca bir #YOK hatası için özelleştirilmiş bir yanıt döndürmek istiyorsanız kullanışlıdır.

IFNA İşlevinin Sözdizimi :

IFNA(value, value_if_na)

Aşağıdaki satış raporları tablosuna sahip olduğunuzu ve tablodan birkaç kalemin Satış tutarını çekmek istediğinizi varsayalım. Bunu yapmak için şu basit DÜŞEYARA formülünü kullanıyoruz:

=VLOOKUP(F2,$A$2:$D$7,4,FALSE)

Yukarıdaki formül G2 hücresine girilir ve aynı formül doldurma tutamacı kullanılarak G2:G6 aralığına uygulanır. Bunu yaptığımızda bir #DEĞER elde ederiz! ve iki öğe için bir #YOK hatası.

Bu hataları işlemek için yukarıdaki DÜŞEYARA formülünü EĞERHATA işlevinin içine yerleştirebilirsiniz:

=IFERROR(VLOOKUP(F2,$A$2:$D$7,4,FALSE),"Not Found")

Bu EĞERHATA formülü tüm hataları işleyecek ve bir hata bulunduğunda “Bulunamadı” mesajını döndürecektir. Yukarıdaki formül tüm G2:G6 aralığına uygulanır.

Ama biz bunu istemiyoruz, sadece tabloda olmayan ürünler için (Domatesler) “Bulunamadı” mesajını göstermek istiyoruz. Bu, yalnızca arama tablosunda arama değeri yoksa görünen #YOK hatalarını yakalamamız ve işlememiz gerektiği anlamına gelir. Bunu yapmak için DÜŞEYARA işlevini IFNA işlevinin içine yerleştirmemiz gerekir.

Yalnızca #N/A hatalarını yakalamak için aşağıdaki formülü kullanın:

=IFNA(VLOOKUP(F2,$A$2:$D$7,4,FALSE),"Not Found")

Yukarıdaki formül G2:G6 aralığına uygulanır. DÜŞEYARA işlevini yalnızca #YOK hatası için kontrol eder ve öğe tabloda bulunmazsa “Bulunamadı” metnini döndürür. Aşağıda görebileceğiniz gibi, yalnızca G6 hücresinde oluşan #N/A’yı yakalar ve mesajı döndürür. Ve #DEĞER’i yakalamaz! G4 hücresinde oluşan ve hatayı olduğu gibi gösteren hata.

Bu kadar.

İlginizi Çekebilir!

How to Use Midjourney v6

Midjourney v6 Nasıl Kullanılır

Her zamankinden çok daha gerçekçi görüntüler oluşturmak için Midjourney'in en yeni modelini kullanın.

Bir yanıt yazın

E-posta adresiniz yayınlanmayacak. Gerekli alanlar * ile işaretlenmişlerdir